using Pumas
Fitting Non-Identifiable and Poorly Identifiable Models using Bayesian Inference
In this tutorial, we will see how to use Bayesian inference in Pumas to fit a non-identifiable (or a poorly identifiable) model by sampling from the full posterior. Unlike maximum likelihood estimation methods which only find point estimates for the model parameters, Bayesian methods can be used to sample from the full posterior of the model parameters making it more robust to identifiability issues.
1 Model Identifiability
One of the goals of statistical learning is to identify the underlying parameter values in a parametric model that best fit the observed data. In many practical scenarios, some parameters in a model may not be identifiable, for one of the following problems:
- The model is over-parameterized with redundant parameters, where a continuum of parameter values, e.g \(0 \leq \theta \leq 1\), would all give identical model predictions. This tends to happen when a dynamical model has many compartments and associated parameters but only one or a few compartments are observed. Another case where this happens is if there is a typo in the model where a parameter is not used everywhere it should.
- The model has symmetries such that a discrete set of parameter values, e.g. \(\theta = -1\) or \(\theta = 1\), give identical model predictions. This tends to happen with inappropriate use of the “absolute value” function (
abs) if used on a function that can be either negative or positive potentially creating 2 separate modes. This problem can sometimes be fixed by using appropriate parameter bounds, e.g. \(\theta \geq 0\), in the model. - The data is insufficient to learn some parameters’ values but more data would have been sufficient.
The first 2 problems are problems in the model describing structural non-identifiability and the third problem is a problem in the data or data-model mismatch describing practical non-identifiability (sometimes called non-estimability).
| Type of Identifiability | Description |
|---|---|
| Globally Structurally Identifiable | Every set of parameter values \(\theta\) makes a unique model prediction \(\mu(\theta)\). |
| Globally Practically Identifiable | Globally structurally identifiable and there is enough data to estimate the data-generating parameter values. |
| Locally Structurally Identifiable | Only dis-connected parameters values \(\{\theta_1, \theta_2, \dots, \theta_m\}\) can result in the same model prediction \(\mu\), i.e. \(\mu(\theta_1) = \mu(\theta_2) = \dots = \mu(\theta_m)\). However, in the neighborhood \(N(\theta)\) of each set of parameters \(\theta\), each \(\theta' \in N(\theta)\) results in a unique model prediction \(\mu(\theta')\). |
| Locally Practically Identifiable | Locally structurally identifiable and there is enough data to estimate the (potentially non-unique but dis-connected) data-generating parameter values. |
Key Points
- Local (or global) practical identifiablity is what we usually want in analyses.
- Practical identifiability (estimability) implies structural identifiability.
Poor Identifiability
When a model may be identifiable in exact arithmetic but its identifiability is sensitive to numerical errors in computations, we will call it poorly identifiable. When the term “poorly identifiable models” is used in the rest of this tutorial, this also includes truly non-identifiable models.
2 Example
Let’s consider an example of fitting a poorly identifiable model.
2.1 Loading Pumas
First, let’s load Pumas:
2.2 Two Compartment Model
Now let’s define a single-subject, 2-compartment model with a depot, central and peripheral compartments and a proportional error model.
model = @model begin
@param begin
θ ∈ VectorDomain(lower = zeros(5))
σ ∈ RealDomain(lower = 0.0)
end
@pre begin
CL = θ[1]
Vc = θ[2]
Ka = θ[3]
Vp = θ[4]
Q = θ[5]
end
@dynamics begin
Depot' = -Ka * Depot
Central' = Ka * Depot - (CL + Q) / Vc * Central + Q / Vp * Peripheral
Peripheral' = Q / Vc * Central - Q / Vp * Peripheral
end
@derived begin
cp := @. Central / Vc
dv ~ @. Normal(cp, abs(cp) * σ + 1e-6)
end
endPumasModel
Parameters: θ, σ
Random effects:
Covariates:
Dynamical variables: Depot, Central, Peripheral
Derived: dv
Observed: dv
Subject Model vs Population Model
Note that studying the identifiability of subject models is still relevant when fitting a population version of the model with typical values and random effects. The reason is that when evaluating the log likelihood using the Laplace method or first-order conditional estimation (FOCE), one of the steps involved is finding the empirical Bayes estimates (EBE) which is essentially fitting a subject’s version of the model, fixing population parameters and estimating random effects. Non-identifiability in the EBE estimation can often cause the EBE estimation to fail or to be so numerically unstable that the population parameters’ fit itself fails because the marginal likelihood (and its gradient) computed with Laplace/FOCE relied on incorrect or numerically unstable EBEs.
2.3 Parameter Values
Let’s define some parameter values to use for simulation.
params = (θ = [35, 100, 0.5, 210, 30], σ = 0.1)(θ = [35.0, 100.0, 0.5, 210.0, 30.0],
σ = 0.1,)2.4 Subject Definition
Next we define a subject skeleton with a single bolus dose and no observations.
skeleton = Subject(
id = 1,
time = 0.0:0.5:30.0,
events = DosageRegimen(3000, time = 0.0, cmt = 1),
observations = (; dv = nothing),
)Subject
ID: 1
Events: 1
Observations: dv: (n=61)2.5 Fisher Information Matrix
The expected Fisher Information Matrix (FIM) is an important diagnostic which can be used to detect local practical identifiability (LPI) given the model and the experiment design [1]. The first order approximation of the expected FIM [2,3] has also been used successfully to analyze the LPI of pharmacometric nonlinear mixed effect (NLME) models [4,5,6].
The positive definiteness (non-singularity) of the expected FIM \(F(\theta)\) at parameters \(\theta\) is a sufficient condition for LPI at \(\theta\). Under more strict assumptions which are more difficult to verify, the positive definiteness of \(F(\theta)\) is even a necessary condition for LPI [1].
To compute a first-order approximation of the expected FIM, we will use the OptimalDesign package:
using OptimalDesign
times = OptimalDesign.ObsTimes(skeleton.time)
F = OptimalDesign.fim(model, [skeleton], params, [times], FO())6×6 Symmetric{Float64, Matrix{Float64}}:
1.29489 -0.0538762 13.6934 0.0254882 -0.218694 -2.68028
-0.0538762 0.0188821 -4.38015 -0.00168545 0.0296863 -0.325336
13.6934 -4.38015 1054.71 0.635262 -7.13309 66.7482
0.0254882 -0.00168545 0.635262 0.00215196 -0.00487912 -0.0895271
-0.218694 0.0296863 -7.13309 -0.00487912 0.144604 -0.720992
-2.68028 -0.325336 66.7482 -0.0895271 -0.720992 1667.742.6 Procedure for Detecting Practical Non-Identifiability
Next, let’s do an eigenvalue decomposition of F to find the smallest eigenvalue. The smallest eigenvalue is always the first one because they are sorted.
E = eigen(F)
E.values[1]9.646842560443467e-5It is close to 0! This implies that the matrix is very close to being singular. While this is not strictly a proof of local non-identifiability, it is one step towards detecting non-identifiability.
Tip
The non-singularity of the expected FIM is generally only a sufficient (not necessary) condition for local identifiability. So there are some locally identifiable models that have a singular or undefined expected FIM. However, there is a subclass of models satisfying strict assumptions for which the non-singularity of the expected FIM is a necessary condition for local identifiability [1]. In practice, these assumptions are difficult to verify for a general model but if our model happens to satisfy these assumptions, then a singular expected FIM would imply local non-identifiability. In that case, the eigenvector(s) corresponding to the 0 eigenvalue would be useful diagnostics as they point in the directions along which changes in the parameters will have no effect on the log likelihood.
To summarize:
- Being “Non-Singular” Isn’t Always a Must: A non-singular expected FIM always signals that a model is “locally identifiable” (meaning you can find a locally unique solution for its parameters). However, some locally identifiable models can still have singular or undefined expected FIM.
- Sometimes, It’s Absolutely Necessary: There’s a special group of models where a non-singular expected FIM is required to be locally identifiable. It’s hard to know if your model falls into this group.
- Practical Use: Even if your expected FIM is singular, it may be a helpful diagnostic. The eigenvectors of the FIM with 0 eigenvalues show you directions where changing the model’s parameters may not affect the model’s predictions – this may help you pinpoint where the model is fuzzy.
To prove if a model is practically non-identifiable, it suffices to find a single set \(\Theta\) such that for all parameters \(\theta \in \Theta\), the log likelihood is unchanged. To find \(\Theta\) numerically, one can
- Assume parameter values \(\theta_0\),
- Define a criteria for changing the parameters \(\theta\) from their current values \(\theta_0\), and then create a candidate set of parameters \(\Theta_c\),
- Simulate synthetic data using the parameters \(\theta_0\),
- Evaluate the log likelihood \(L(\theta)\) for all \(\theta \in \Theta_c\),
- Evaluate the sensitivity of the log likelihood to local changes within \(\Theta_c\).
One way to construct a candidate \(\Theta_c\) is as the set \(\{\theta_0 + \alpha \cdot d : \alpha \in [-\epsilon, \epsilon] \}\) for a small \(\epsilon > 0\), where \(d\) is an eigenvector corresponding to the smallest eigenvalue of the expected FIM, \(F\). The sensitivity of the log likelihood to changes within \(\Theta_c\) can then be quantified as the average value of:
\[ \Bigg( \frac{L(\theta_0 + \alpha \cdot d) - L(\theta_0)}{\alpha} \Bigg)^2 \]
for all \(\alpha \in [-\epsilon, \epsilon]\), \(\alpha \neq 0\). Let’s follow this procedure for the above model assuming \(\theta_0\) is params.
2.7 Simulating Data
Here we simulate a synthetic subject using the skeleton subject we have. We fix the seed of the pseudo-random number generator for reproducibility.
using Random
rng = Random.default_rng()
Random.seed!(rng, 12345)
pop = [Subject(simobs(model, skeleton, params; rng))]Population
Subjects: 1
Observations: dvTo evaluate the log likelihood of params given pop, we can use the loglikelihood function:
ll0 = loglikelihood(model, pop, params, NaivePooled())32.82461166030997Since there are no random effects in this model, we use the NaivePooled() algorithm in Pumas.
2.8 Local Sensitivity Analysis of Log Likelihood
The eigenvectors corresponding to the smallest eigenvalue of F give us the directions that are likely to have the largest standard error in the maximum likelihood estimates. These are the most promising directions to test when constructing candidate sets \(\Theta_c\) for identifiability analysis. To get the eigenvector corresponding to the smallest eigenvalue, you can run:
d = E.vectors[:, 1]6-element Vector{Float64}:
0.006717009021476735
0.8382731175155917
0.0037560578470219614
-0.5451738773535086
0.004939403956445427
-3.137352344503738e-6The order of parameters is the same as the order of definition in the model: θ and then σ.
Note that the potential non-identifiability seems to be mostly in the second and fourth parameter, Vc and Vp. More precisely, the above eigenvector implies that simultaneously increasing Vc and decreasing Vp (or vice versa) by the ratios given in d may have little to no effect on the log likelihood.
Let’s try to add α * d[1:end-1] to params.θ (i.e. move params.θ in the direction d[1:end-1]) and evaluate the log likelihood for different step sizes α. To do that, we will first define a function that moves params.θ and call it on different step values α. These choices of α values correspond to a discrete candidate set \(\Theta_c\).
function moveθ(α)
# unpacking the fields of params to variables with the same names
(; θ, σ) = params
# move θ by step * d[1:end-1]
return (; θ = θ + α * d[1:end-1], σ)
end
# move by both negative and positive steps (excluding α = 0)
αs = vcat(-1e-3 .* (1:10), 1e-3 .* (1:10))20-element Vector{Float64}:
-0.001
-0.002
-0.003
-0.004
-0.005
-0.006
-0.007
-0.008
-0.009
-0.01
0.001
0.002
0.003
0.004
0.005
0.006
0.007
0.008
0.009
0.01newparams = moveθ.(αs)20-element Vector{NamedTuple{(:θ, :σ), Tuple{Vector{Float64}, Float64}}}:
(θ = [34.99999328299098, 99.99916172688249, 0.499996243942153, 210.00054517387736, 29.999995060596042], σ = 0.1)
(θ = [34.999986565981956, 99.99832345376497, 0.49999248788430595, 210.0010903477547, 29.999990121192088], σ = 0.1)
(θ = [34.999979848972934, 99.99748518064746, 0.4999887318264589, 210.00163552163207, 29.99998518178813], σ = 0.1)
(θ = [34.99997313196391, 99.99664690752994, 0.4999849757686119, 210.00218069550942, 29.999980242384176], σ = 0.1)
(θ = [34.99996641495489, 99.99580863441243, 0.49998121971076487, 210.00272586938678, 29.999975302980218], σ = 0.1)
(θ = [34.99995969794587, 99.9949703612949, 0.49997746365291784, 210.00327104326414, 29.99997036357626], σ = 0.1)
(θ = [34.99995298093685, 99.9941320881774, 0.49997370759507087, 210.00381621714146, 29.999965424172306], σ = 0.1)
(θ = [34.999946263927825, 99.99329381505987, 0.49996995153722384, 210.00436139101882, 29.999960484768348], σ = 0.1)
(θ = [34.99993954691881, 99.99245554194236, 0.4999661954793768, 210.00490656489617, 29.999955545364394], σ = 0.1)
(θ = [34.99993282990979, 99.99161726882484, 0.4999624394215298, 210.00545173877353, 29.999950605960436], σ = 0.1)
(θ = [35.00000671700902, 100.00083827311751, 0.500003756057847, 209.99945482612264, 30.000004939403958], σ = 0.1)
(θ = [35.000013434018044, 100.00167654623503, 0.500007512115694, 209.9989096522453, 30.000009878807912], σ = 0.1)
(θ = [35.000020151027066, 100.00251481935254, 0.500011268173541, 209.99836447836793, 30.00001481821187], σ = 0.1)
(θ = [35.00002686803609, 100.00335309247006, 0.5000150242313881, 209.99781930449058, 30.000019757615824], σ = 0.1)
(θ = [35.00003358504511, 100.00419136558757, 0.5000187802892351, 209.99727413061322, 30.000024697019782], σ = 0.1)
(θ = [35.00004030205413, 100.0050296387051, 0.5000225363470822, 209.99672895673586, 30.00002963642374], σ = 0.1)
(θ = [35.00004701906315, 100.0058679118226, 0.5000262924049291, 209.99618378285854, 30.000034575827694], σ = 0.1)
(θ = [35.000053736072175, 100.00670618494013, 0.5000300484627762, 209.99563860898118, 30.000039515231652], σ = 0.1)
(θ = [35.00006045308119, 100.00754445805764, 0.5000338045206232, 209.99509343510383, 30.000044454635606], σ = 0.1)
(θ = [35.00006717009021, 100.00838273117516, 0.5000375605784703, 209.99454826122647, 30.000049394039564], σ = 0.1)Now let’s evaluate the log likelihoods of all these parameter sets.
lls = map(newparams) do p
loglikelihood(model, pop, p, NaivePooled())
end20-element Vector{Float64}:
32.82463258809266
32.824653516776316
32.82467444599981
32.824695375686
32.8247163049834
32.82473723581962
32.82475816602141
32.82477909749674
32.82480002929137
32.824820961111435
32.82459073300738
32.82456980632097
32.8245488798121
32.82452795380517
32.82450702699767
32.824486102815484
32.824465177567234
32.82444425406181
32.824423330072776
32.824402406539846To compute the average sensitivity within \(\Theta_c\), we then call:
sens = abs2.((lls .- ll0) ./ αs)
mean(sens)0.0004379688924138595Not very sensitive! Therefore, we can conclude that the log likelihood is almost the same inside \(\Theta_c\). This is a strong sign of non-identifiability, or at least poor identifiability.
Let’s contrast this with a random direction d2:
d2 = normalize(rand(6))
function moveθ2(α)
# unpacking the fields of params to variables with the same names
(; θ, σ) = params
# move θ by step * d2[1:end-1]
return (; θ = θ + α * d2[1:end-1], σ)
end
newparams2 = moveθ2.(αs)
lls2 = map(newparams2) do p
loglikelihood(model, pop, p, NaivePooled())
end
sens2 = abs2.((lls2 .- ll0) ./ αs)
mean(sens2)1244.447531304962Notice the difference in sensitivity compared to a random direction.
Note
In practice, it can be difficult to be definitive about practical non-identifiability with numerical tests due to the nature of computation in floating point numbers where numerical errors can accumulate and either:
- Mask a truly singular matrix by reporting its smallest eigenvalue as very close to 0 but not exactly 0 in floating point numbers, or
- Make a truly non-singular matrix appear singular because its smallest eigenvalue was close to 0 in exact arithmetic but was computed as exactly 0 in floating point arithmetic.
A small enough average local sensitivity can therefore be taken as numerically equivalent to 0, i.e. local practical non-identifiability. To be more general, we will sometimes use the term poor identifiability to refer to the case when the model is approximately non-identifiable.
3 Fitting a Poorly Identifiable Model
3.1 Maximum Likelihood Estimation
When using maximum likelihood (ML) estimation to fit a poorly identifiable model, the parameter values you get can be dependent on arbitrary factors such as:
- The initial parameter estimates. Optimization algorithms will typically converge to values close to the initial value which is arbitrary.
- Level of noise in the data. Different levels of noise in the data can cause the optimization algorithm to take different trajectories reaching different optimal parameter values at the end.
- The implementation details of the optimization algorithm. For example, some optimization algorithms implicitly favor parameter values with the smallest norm.
Most of these factors have no statistical significance and can be considered arbitrary in any analysis. Therefore, any insights drawn from poorly identifiable parameter values fitted with ML estimation may be flawed. Luckily, the standard error estimation, if done right, will often reveal signs of poor identifiability. However, common techniques for estimating standard errors can often break down when the model is poorly identifiable. For instance,
- Asymptotic estimates of standard errors require the model to be locally identifiable,
- Bootstrap relies on the same arbitrary optimization algorithm for fitting the data resamples so its estimates are as unreliable as the ML estimates. For instance, since all the re-fits in bootstrapping are typically initialized from the ML estimates, there is a high probability that the optimization algorithm will only converge to nearby values, significantly under-estimating the variance in the ML estimates.
- Sampling importance resampling (SIR) may be able to handle non-identifiable models but it requires a good proposal and its results are sensitive to the proposal used.
Example: Sensitivity to Initial Estimates
Let’s fit the model to the same subject but with 2 different sets of initial estimates:
params1 = (θ = [35, 100, 0.5, 210, 30], σ = 0.1)
fpm1 = fit(model, pop, params1, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 -3.282461e+01 5.896801e+01
* time: 0.020066022872924805
1 -3.299541e+01 8.371540e+01
* time: 0.3571889400482178
2 -3.440867e+01 3.937303e+01
* time: 0.3576209545135498
3 -3.550285e+01 3.429323e+01
* time: 0.35799407958984375
4 -3.585802e+01 2.078146e+01
* time: 0.3583500385284424
5 -3.605801e+01 4.208231e+00
* time: 0.35869908332824707
6 -3.606867e+01 5.500193e+00
* time: 0.3590059280395508
7 -3.607820e+01 5.143560e-01
* time: 0.35930609703063965
8 -3.607823e+01 1.670014e-01
* time: 0.35960912704467773
9 -3.607823e+01 6.594682e-03
* time: 0.35991406440734863
10 -3.607823e+01 3.931879e-03
* time: 0.36022210121154785
11 -3.607823e+01 5.365673e-02
* time: 0.3605329990386963
12 -3.607823e+01 2.875459e-02
* time: 0.36083102226257324
13 -3.607823e+01 3.163451e-03
* time: 0.3611431121826172
14 -3.607823e+01 1.189333e-04
* time: 0.3614349365234375FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: 36.078234
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
-----------------
Estimate
-----------------
θ₁ 34.397
θ₂ 103.17
θ₃ 0.46566
θ₄ 204.44
θ₅ 26.234
σ 0.092273
-----------------params2 = (θ = [10.0, 300, 1.0, 10.0, 5], σ = 0.2)
fpm2 = fit(model, pop, params2, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 4.245135e+02 6.802168e+02
* time: 3.0040740966796875e-5
1 1.499850e+02 4.520555e+01
* time: 0.0003750324249267578
2 1.436201e+02 4.485781e+01
* time: 0.0007002353668212891
3 1.108786e+02 4.698780e+01
* time: 0.001001119613647461
4 9.146731e+01 4.889574e+01
* time: 0.0013120174407958984
5 8.587677e+01 4.879782e+01
* time: 0.0017080307006835938
6 8.353852e+01 5.068832e+01
* time: 0.0020720958709716797
7 8.061237e+01 4.922992e+01
* time: 0.002457141876220703
8 7.723482e+01 3.939427e+01
* time: 0.002824068069458008
9 7.347395e+01 6.732180e+01
* time: 0.0031380653381347656
10 6.467070e+01 2.181937e+01
* time: 0.0034410953521728516
11 5.389941e+01 4.260986e+01
* time: 0.0038361549377441406
12 4.899559e+01 4.746853e+01
* time: 0.004194021224975586
13 4.636064e+01 4.389414e+01
* time: 0.0045011043548583984
14 4.311120e+01 3.667380e+01
* time: 0.0048182010650634766
15 3.452695e+01 4.210878e+01
* time: 0.005176067352294922
16 2.786722e+01 4.181505e+01
* time: 0.005564212799072266
17 2.167865e+01 2.502622e+01
* time: 0.005942106246948242
18 2.102586e+01 3.073394e+01
* time: 0.0062580108642578125
19 2.012361e+01 9.155807e+00
* time: 0.006595134735107422
20 1.993999e+01 8.931312e+00
* time: 0.006916046142578125
21 1.899136e+01 3.290293e+01
* time: 0.007234096527099609
22 1.831295e+01 1.555682e+01
* time: 0.0075550079345703125
23 1.764099e+01 4.156266e+00
* time: 0.007891178131103516
24 1.734278e+01 4.764555e+00
* time: 0.008212089538574219
25 1.692204e+01 5.545118e+00
* time: 0.008546113967895508
26 1.576408e+01 6.312614e+00
* time: 0.008935213088989258
27 1.433865e+01 8.298700e+00
* time: 0.009329080581665039
28 1.402269e+01 1.935485e+01
* time: 0.009733200073242188
29 1.388981e+01 5.313929e+00
* time: 0.010088205337524414
30 1.380201e+01 6.598755e+00
* time: 0.010428190231323242
31 1.361376e+01 1.819850e+01
* time: 0.01077413558959961
32 1.307080e+01 3.715701e+01
* time: 0.011115074157714844
33 1.084752e+01 4.989789e+01
* time: 0.01147603988647461
34 9.107761e+00 3.568940e+01
* time: 0.012135028839111328
35 8.799303e+00 1.470967e+02
* time: 0.012613058090209961
36 6.685368e+00 4.816807e+01
* time: 0.012987136840820312
37 4.048434e+00 5.757686e+01
* time: 0.013351202011108398
38 -4.570968e+00 4.010359e+01
* time: 0.022669076919555664
39 -6.951249e+00 9.481085e+01
* time: 0.02312016487121582
40 -8.241067e+00 2.924279e+01
* time: 0.058889150619506836
41 -9.267379e+00 1.592312e+01
* time: 0.05946922302246094
42 -9.300539e+00 6.235892e+00
* time: 0.059847116470336914
43 -9.408955e+00 4.087560e+00
* time: 0.06021714210510254
44 -9.420626e+00 5.730458e+00
* time: 0.060595035552978516
45 -9.435635e+00 8.693778e+00
* time: 0.060967206954956055
46 -9.439794e+00 8.483929e+00
* time: 0.06133913993835449
47 -9.443618e+00 7.807829e+00
* time: 0.061712026596069336
48 -9.453743e+00 6.452476e+00
* time: 0.06208920478820801
49 -9.479753e+00 3.781804e+00
* time: 0.06245613098144531
50 -9.545875e+00 5.189641e+00
* time: 0.0628361701965332
51 -9.621161e+00 2.998542e+01
* time: 0.06320023536682129
52 -9.788354e+00 2.377897e+01
* time: 0.0635671615600586
53 -9.957783e+00 2.804857e+01
* time: 0.06398200988769531
54 -1.016832e+01 2.937980e+01
* time: 0.06439900398254395
55 -1.046535e+01 3.264929e+01
* time: 0.06482219696044922
56 -1.071184e+01 7.422024e+00
* time: 0.06519007682800293
57 -1.074836e+01 1.458278e+01
* time: 0.06560301780700684
58 -1.088324e+01 1.552006e+01
* time: 0.0660099983215332
59 -1.094332e+01 1.034929e+01
* time: 0.0663611888885498
60 -1.100763e+01 9.505009e+00
* time: 0.06671714782714844
61 -1.101755e+01 1.637700e+00
* time: 0.06706619262695312
62 -1.101926e+01 9.140574e-01
* time: 0.0674130916595459
63 -1.101993e+01 3.661381e-01
* time: 0.06777000427246094
64 -1.102009e+01 1.784483e-01
* time: 0.06812119483947754
65 -1.102013e+01 2.946407e-02
* time: 0.0684661865234375
66 -1.102013e+01 3.293414e-03
* time: 0.06882500648498535
67 -1.102013e+01 5.169943e-04
* time: 0.06917619705200195FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: 11.020132
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
----------------
Estimate
----------------
θ₁ 30.963
θ₂ 214.26
θ₃ 55.46
θ₄ 169.43
θ₅ 12.071
σ 0.13904
----------------Now let’s display the estimates of θ side by side:
hcat(coef(fpm1).θ, coef(fpm2).θ)5×2 Matrix{Float64}:
34.3968 30.9631
103.168 214.264
0.465659 55.4603
204.442 169.429
26.2337 12.0709Notice the significant difference in the final estimates when changing nothing but the initial estimates. Also note that the 2 sets of coefficients are not in the same neighbourhood and don’t have similar log likelihoods. This is indicative of the existence of multiple dis-connected local optima.
Example: Sensitivity to Noise Level
To demonstrate the sensitivity to noise level, we will re-simulate the synthetic subject from the same pseudo-random number generator and seed but using a higher σ.
rng = Random.default_rng()
Random.seed!(rng, 12345)
newparams = (; θ = params.θ, σ = 0.2)
newpop = [Subject(simobs(model, skeleton, newparams; rng))]Population
Subjects: 1
Observations: dvNow let’s do the fit once with pop and once with newpop:
fpm1 = fit(model, pop, params, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 -3.282461e+01 5.896801e+01
* time: 2.3126602172851562e-5
1 -3.299541e+01 8.371540e+01
* time: 0.00045609474182128906
2 -3.440867e+01 3.937303e+01
* time: 0.0008091926574707031
3 -3.550285e+01 3.429323e+01
* time: 0.0011630058288574219
4 -3.585802e+01 2.078146e+01
* time: 0.001497030258178711
5 -3.605801e+01 4.208231e+00
* time: 0.0018410682678222656
6 -3.606867e+01 5.500193e+00
* time: 0.002147197723388672
7 -3.607820e+01 5.143560e-01
* time: 0.0024471282958984375
8 -3.607823e+01 1.670014e-01
* time: 0.0027430057525634766
9 -3.607823e+01 6.594682e-03
* time: 0.0030372142791748047
10 -3.607823e+01 3.931879e-03
* time: 0.003341197967529297
11 -3.607823e+01 5.365673e-02
* time: 0.0036330223083496094
12 -3.607823e+01 2.875459e-02
* time: 0.003930091857910156
13 -3.607823e+01 3.163451e-03
* time: 0.0042340755462646484
14 -3.607823e+01 1.189333e-04
* time: 0.004525184631347656FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: 36.078234
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
-----------------
Estimate
-----------------
θ₁ 34.397
θ₂ 103.17
θ₃ 0.46566
θ₄ 204.44
θ₅ 26.234
σ 0.092273
-----------------fpm2 = fit(model, newpop, newparams, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 8.763976e+00 2.735808e+01
* time: 2.2172927856445312e-5
1 8.405325e+00 2.531358e+01
* time: 0.00044798851013183594
2 6.620382e+00 1.286061e+01
* time: 0.0008070468902587891
3 5.297438e+00 8.779519e+00
* time: 0.0011420249938964844
4 4.963913e+00 3.840318e+00
* time: 0.0014979839324951172
5 4.930293e+00 1.184668e+01
* time: 0.0017931461334228516
6 4.873975e+00 3.753008e+00
* time: 0.0021011829376220703
7 4.858307e+00 2.308575e+00
* time: 0.0024650096893310547
8 4.854947e+00 8.434789e-02
* time: 0.0027680397033691406
9 4.854713e+00 7.173484e-02
* time: 0.003062009811401367
10 4.853126e+00 8.197275e-01
* time: 0.0033769607543945312
11 4.851996e+00 1.269989e+00
* time: 0.0036749839782714844
12 4.850709e+00 1.179594e+00
* time: 0.003971099853515625
13 4.849908e+00 1.616557e-01
* time: 0.004273176193237305
14 4.849724e+00 8.747458e-01
* time: 0.004570960998535156
15 4.849534e+00 1.703991e-01
* time: 0.004878044128417969
16 4.849431e+00 1.385412e-01
* time: 0.005185127258300781
17 4.849400e+00 1.192473e-01
* time: 0.005485057830810547
18 4.849395e+00 8.727150e-03
* time: 0.005792140960693359
19 4.849394e+00 2.408209e-02
* time: 0.006086111068725586
20 4.849394e+00 1.491013e-03
* time: 0.006392002105712891
21 4.849394e+00 1.658892e-04
* time: 0.006692171096801758FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: -4.8493937
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
----------------
Estimate
----------------
θ₁ 33.85
θ₂ 125.52
θ₃ 0.50012
θ₄ 192.8
θ₅ 22.25
σ 0.18103
----------------Now let’s display the estimates of θ side by side:
hcat(coef(fpm1).θ, coef(fpm2).θ)5×2 Matrix{Float64}:
34.3968 33.8499
103.168 125.517
0.465659 0.500121
204.442 192.8
26.2337 22.2497Given that we have many observations per subject, this level of fluctuation due to a higher noise is a symptom of non-identifiability. Also note the big difference compared to the true data-generating parameter values!
params.θ5-element Vector{Float64}:
35.0
100.0
0.5
210.0
30.0
Summary
In this section, we have demonstrated beyond reasonable doubt that ML estimation workflows can be unreliable when fitting poorly identifiable models, potentially leading to erroneous conclusions in a study. So if we cannot rely on ML estimation for fitting poorly identifiable models, what can we use? The answer is Bayesian inference.
3.2 Bayesian Inference
Using Bayesian methods to sample from the posterior of the parameter estimates is a mathematically sound way to fit non-identifiable models because even non-identifiable models have a well-defined posterior distribution, when their parameters are assigned prior distributions. If multiple parameter values all fit the data well, then all such values will be plausible samples from the posterior distribution, assuming reasonable priors were used.
3.2.1 Model Definition
Let’s see how to minimally change our model above to make it Bayesian using a weakly informative priors “roughly in the ballpark”:
bayes_model = @model begin
@param begin
θ ~ MvLogNormal([log(50), log(150), log(1.0), log(100.0), log(10.0)], I(5))
σ ~ Uniform(0.0, 1.0)
end
@pre begin
CL = θ[1]
Vc = θ[2]
Ka = θ[3]
Vp = θ[4]
Q = θ[5]
end
@dynamics begin
Depot' = -Ka * Depot
Central' = Ka * Depot - (CL + Q) / Vc * Central + Q / Vp * Peripheral
Peripheral' = Q / Vc * Central - Q / Vp * Peripheral
end
@derived begin
cp := @. Central / Vc
dv ~ @. Normal(cp, abs(cp) * σ + 1e-6)
end
endPumasModel
Parameters: θ, σ
Random effects:
Covariates:
Dynamical variables: Depot, Central, Peripheral
Derived: dv
Observed: dv3.2.2 Sampling from the Posterior
Now to fit it, we need to pass an instance of BayesMCMC as the algorithm in fit. In this case, we used 4 chains for sampling with 3000 samples per chain out of which the first 1500 samples will be used to adapt the mass matrix and step size of the No-U-Turn sampler (NUTS) used in Pumas. All the chains are also parallelized using multi-threading.
# Setting the pseudo-random number generator's seed for reproducibility
rng = Pumas.default_rng()
Random.seed!(54321)
bayes_alg = BayesMCMC(;
nsamples = 3000,
nadapts = 1500,
nchains = 4,
ensemblealg = EnsembleThreads(),
rng,
)
bayes_fpm = fit(bayes_model, pop, params, bayes_alg)[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.Chains MCMC chain (3000×6×4 Array{Float64, 3}):
Iterations = 1:1:3000
Number of chains = 4
Samples per chain = 3000
Wall duration = 31.66 seconds
Compute duration = 120.93 seconds
parameters = θ₁, θ₂, θ₃, θ₄, θ₅, σ
Summary Statistics
parameters mean std mcse ess_bulk ess_tail rhat ⋯
Symbol Float64 Float64 Float64 Float64 Float64 Float64 ⋯
θ₁ 34.2717 0.6362 0.0086 5551.3806 6413.5813 1.0007 ⋯
θ₂ 138.8467 34.8978 0.7102 2487.3817 3979.1213 1.0017 ⋯
θ₃ 0.6511 0.1843 0.0036 2529.3840 3923.1250 1.0017 ⋯
θ₄ 190.0993 18.8466 0.3440 3108.8136 4530.2519 1.0011 ⋯
θ₅ 23.2832 3.0216 0.0550 3072.9410 4973.3905 1.0014 ⋯
σ 0.0983 0.0097 0.0001 5752.4801 5753.0447 1.0001 ⋯
1 column omitted
Quantiles
parameters 2.5% 25.0% 50.0% 75.0% 97.5%
Symbol Float64 Float64 Float64 Float64 Float64
θ₁ 33.0120 33.8490 34.2784 34.6904 35.5084
θ₂ 71.9391 111.2588 143.1361 166.0002 197.2179
θ₃ 0.3491 0.5018 0.6481 0.7779 1.0266
θ₄ 158.1985 176.6931 188.1775 201.7879 231.2874
θ₅ 17.2545 21.1185 23.4505 25.4717 28.8015
σ 0.0813 0.0916 0.0976 0.1041 0.1195
Now let’s discard the NUTS warmup samples as burn-in:
bayes_fpm_samples = Pumas.discard(bayes_fpm, burnin = 1500)Chains MCMC chain (1500×6×4 Array{Float64, 3}):
Iterations = 1:1:1500
Number of chains = 4
Samples per chain = 1500
Wall duration = 31.66 seconds
Compute duration = 120.93 seconds
parameters = θ₁, θ₂, θ₃, θ₄, θ₅, σ
Summary Statistics
parameters mean std mcse ess_bulk ess_tail rhat ⋯
Symbol Float64 Float64 Float64 Float64 Float64 Float64 ⋯
θ₁ 34.2756 0.6322 0.0121 2711.9918 3407.4054 1.0004 ⋯
θ₂ 139.2094 35.1573 0.9827 1324.9363 2301.4196 1.0008 ⋯
θ₃ 0.6537 0.1863 0.0050 1342.8480 2090.4298 1.0009 ⋯
θ₄ 189.6751 18.9777 0.4879 1563.5781 2411.6157 1.0012 ⋯
θ₅ 23.2415 3.0198 0.0770 1562.4658 2631.9980 1.0023 ⋯
σ 0.0982 0.0097 0.0002 3419.5267 3247.6062 1.0003 ⋯
1 column omitted
Quantiles
parameters 2.5% 25.0% 50.0% 75.0% 97.5%
Symbol Float64 Float64 Float64 Float64 Float64
θ₁ 33.0335 33.8569 34.2767 34.6907 35.5135
θ₂ 71.6983 112.0005 143.9073 166.3824 197.3886
θ₃ 0.3484 0.5045 0.6515 0.7826 1.0302
θ₄ 157.8467 176.2235 187.5045 201.4310 231.8597
θ₅ 17.2540 21.0390 23.4050 25.4315 28.6638
σ 0.0808 0.0914 0.0976 0.1041 0.1190
Notice how Bayesian inference was able to quantify the uncertainty in the non-identifiable parameters (mostly θ₂ which is Vc and θ₄ which is Vp) reflected in the large standard deviation of the marginal posterior of some parameters, std, relative to its mean value, mean. This is consistent with the eigenvector d we used earlier to prove that the model is poorly identifiable which also showed the poor identifiability was mostly prevalent in these 2 parameters.
d6-element Vector{Float64}:
0.006717009021476735
0.8382731175155917
0.0037560578470219614
-0.5451738773535086
0.004939403956445427
-3.137352344503738e-63.2.3 Convergence Diagnostics
By default, we print summary statistics and a few convergence diagnostics: effective samples size (ess_bulk) and \(\hat{R}\) (rhat). In this case, the diagnostics look reasonable. The rhat is close to 1 and the minimum ess_bulk is around 1000.
Next we show the trace plot of all the parameters
using PumasPlots
trace_plot(bayes_fpm_samples; linkyaxes = false)
It can be seen that the chains are mostly well mixed. Occasional jumps seem to happen which may indicate the presence of another mode in the posterior with a relatively small probability mass.
Now let’s look at the auto-correlation plot:
autocor_plot(bayes_fpm_samples; linkyaxes = false)
Some auto-correlation seems to persist in some chains so let’s try some thinning, by keeping only one out of every 5 samples.
thin_bayes_fpm_samples = Pumas.discard(bayes_fpm, burnin = 1500, ratio = 0.2)
autocor_plot(thin_bayes_fpm_samples; linkyaxes = false)
Looks better!
To Thin Or Not To Thin
In general, thinning is not recommended unless there are extremely high levels of auto-correlation in the samples. This is because the thinned samples will always have less information than the full set of samples before thinning. However, we perform thinning in this tutorial for demonstration purposes.
3.2.4 Posterior Predictive Check
Now let’s do a posterior predictive check by first simulating 1000 scenarios from the posterior distribution of the response including residual noise.
obstimes = 0.0:0.5:30.0
sims = simobs(bayes_fpm_samples; samples = 1000, simulate_error = true, obstimes)[ Info: Sampling 1000 sample(s) from the posterior predictive distribution of each subject.Simulated population (Vector{<:Subject})
Simulated subjects: 1000
Simulated variables: dvthen we can do a visual predictive check (VPC) plot using the simulations
vpc_res = vpc(sims; observations = [:dv], ensemblealg = EnsembleThreads())
vpc_plt = vpc_plot(
vpc_res;
simquantile_medians = true,
observations = true,
axis = (xlabel = "Time (h)", ylabel = "Concentration", xticks = 0:2:30),
)[ Info: Detected 1000 scenarios and 1 subjects in the input simulations. Running VPC.
[ Info: Continuous VPC
Summary
With very few changes in the model and a few lines of code, we were able to obtain samples from the full posterior of the parameters of our poorly identifiable model.
4 Uncertainty Propagation, Queries and Decision Making
Just because a model is non-identifiable does not mean that the model is useless or less correct. In fact, more correct models that incorporate more biological processes tend to be non-identifiable because we can only observe/measure very few variables in the model, while simplified models are more likely to be identifiable. Given samples from the posterior of a non-identifiable model, one can do the following:
- Propagate the uncertainty forward to the predictions to get samples from the posterior predictive distribution, instead of relying on a single prediction using the ML estimates.
Value of Uncertainty Quantification
Parameter uncertainty due to structural non-identifiability will by definition have no effect on the model’s predictions when predicting the observed response. However, uncertainty due to practical non-identifiability, or otherwise insufficient data, can have an impact on the model’s predictions. In this case, basing decisions on the full posterior predictive distribution instead of a single prediction from the ML estimates will make the decisions more robust to parameter uncertainty due to insufficient observations and model misspecification.
- Ask probabilistic questions given your data. For example, what’s the probability that the drug effect is \(> 0\)? Or what’s the probability that the new drug
Ais better than the control drugBafter only 3 months of data? Or what’s the probability of satisfying a therapeutic criteria for efficacy and safety given the current dose? - What-if analysis (aka counter-factual simulation) and dose optimization. For example, you can make predictions assuming the subject is a pediatric using the model parameters’ posterior inferred from an adult’s data. Or you can test different dose levels to select the best dose according to some therapeutic criteria. This can also be done in the non-Bayesian setting.
4.1 Probabilistic Questions
In this section, we show how to
- Estimate the probability that a parameter is more than a specific value, and
- Estimate the probability that the subject satisfies a desired therapeutic criteria. From there, one can simulate multiple doses and choose the dose that maximizes this probability.
To estimate the probability that CL > 35, we can run:
mean(bayes_fpm_samples) do p
p.θ[1] > 35
end0.12316666666666666To estimate the probability that a subject satisfies a desired therapeutic criteria, we first simulate from the posterior predictive distribution (without residual error):
ipreds = simobs(bayes_fpm_samples; samples = 1000, simulate_error = false, obstimes)[ Info: Sampling 1000 sample(s) from the posterior predictive distribution of each subject.Simulated population (Vector{<:Subject})
Simulated subjects: 1000
Simulated variables: dvNext, we can estimate the area-under-curve (auc) and maximum drug concentration (cmax) given the different posterior samples.
using NCA
nca_params = postprocess(ipreds) do gen, obs
pk_auc = NCA.auc(gen.dv, obstimes)
pk_cmax = NCA.cmax(gen.dv, obstimes)
(; pk_auc, pk_cmax)
end1000-element Vector{NamedTuple{(:pk_auc, :pk_cmax), Tuple{Float64, Float64}}}:
(pk_auc = 87.6147966349493, pk_cmax = 10.013798185252782)
(pk_auc = 88.31424559508336, pk_cmax = 9.789165230261364)
(pk_auc = 88.75828073298457, pk_cmax = 10.029546400367382)
(pk_auc = 87.29334623858104, pk_cmax = 9.738787323640766)
(pk_auc = 87.8129360783117, pk_cmax = 10.486457224781251)
(pk_auc = 87.59213300895905, pk_cmax = 9.750676538833966)
(pk_auc = 86.23641839036192, pk_cmax = 9.378092944834435)
(pk_auc = 89.31657872940664, pk_cmax = 10.680391550054562)
(pk_auc = 87.93692588507585, pk_cmax = 9.798430859500403)
(pk_auc = 84.97763290579462, pk_cmax = 9.53735688460069)
⋮
(pk_auc = 88.539629765938, pk_cmax = 9.876602591189135)
(pk_auc = 87.62314468227474, pk_cmax = 9.970363818400937)
(pk_auc = 87.9851235253784, pk_cmax = 9.476558219684833)
(pk_auc = 86.85320018903666, pk_cmax = 9.781408991180923)
(pk_auc = 87.7317790733621, pk_cmax = 9.85690898774379)
(pk_auc = 86.18713295905992, pk_cmax = 9.655455607105308)
(pk_auc = 85.65003215158697, pk_cmax = 9.707174283791003)
(pk_auc = 87.16907553871282, pk_cmax = 10.140719203792132)
(pk_auc = 86.889668815347, pk_cmax = 9.76594802688905)Finally, we can estimate the probability of satisfying a therapeutic criteria.
prob = mean(nca_params) do p
p.pk_auc > 90 && p.pk_cmax < 15.0
end0.028To compute the probability of efficacy and safety separately, one can instead run:
prob1 = mean(nca_params) do p
p.pk_auc > 90
end
prob2 = mean(nca_params) do p
p.pk_cmax < 15.0
end
prob1, prob2(0.028, 1.0)4.2 Counter-factual Analysis and Dose Optimization
After developing a model, one may be interested in simulating scenarios, e.g. different covariates or doses, that have not been observed in the data while reusing the same posterior distribution of the parameters learnt from the data. This can be used to select a new dose that maximizes the probabilities of efficacy and safety simultaneously given the previously observed data.
In Pumas, you can do this by defining a new subject that includes the new covariates or dose and then passing that to simobs. First, let’s define a new skeleton subject that represents our counter-factual scenario where a dose of 3200 was administered instead of the 3000 used in the observed case:
cf_skeleton = Subject(
id = 1,
time = 0.0:0.5:30.0,
events = DosageRegimen(3200, time = 0.0, cmt = 1),
observations = (; dv = nothing),
)Subject
ID: 1
Events: 1
Observations: dv: (n=61)To simulate from the posterior predictive distribution of this new subject using the posterior of the parameters, you can run:
cf_ipreds = simobs(
thin_bayes_fpm_samples,
cf_skeleton;
samples = 1000,
simulate_error = false,
obstimes,
subject = 1,
)[ Info: Simulating 1000 sample(s) from the posterior predictive distribution of subject 1 using the dose and covariates in the input subject.Simulated population (Vector{<:Subject})
Simulated subjects: 1000
Simulated variables: dvWe can then re-evaluate the probability of satisfying a therapeutic criteria:
cf_nca_params = postprocess(cf_ipreds) do gen, obs
pk_auc = NCA.auc(gen.dv, obstimes)
pk_cmax = NCA.cmax(gen.dv, obstimes)
(; pk_auc, pk_cmax)
end
cf_prob = mean(cf_nca_params) do p
p.pk_auc > 90 && p.pk_cmax < 15.0
end0.958We can see that the probability increased. To understand why, let’s look at the probabilities of the auc and cmax criteria separately:
cf_prob1 = mean(cf_nca_params) do p
p.pk_auc > 90
end
cf_prob2 = mean(cf_nca_params) do p
p.pk_cmax < 15.0
end
cf_prob1, cf_prob2(0.958, 1.0)Contrast this to the old dose’s probabilities:
prob1, prob2(0.028, 1.0)Note that this example was not particularly interesting because of the dense sampling which despite of it, the uncertainty in the parameters was still high. This implies that the uncertainty was largely due to structural identifiability issues in the model. Since uncertainty in parameters due to structural non-identifiability does not affect the model predictions, the posterior predictive distribution was much more concentrated than the parameters’ posterior.
To estimate the mean and standard deviation of the predictions at each point in time we can run:
μs = mean(ipreds) do gen, obs
gen.dv
end
σs = std(ipreds) do gen, obs
gen.dv
end61-element Vector{Float64}:
0.0
0.3200815533301676
0.3867827044258277
0.36447696658247003
0.3250484170074878
0.29139534443971904
0.26464223039021867
0.2408145529455393
0.21752320564244282
0.19452288323438635
⋮
0.014029952719459083
0.014292232934001685
0.014605374595107204
0.014955511894308481
0.015330424622365146
0.01571965440462161
0.01611445855788043
0.01650767046972307
0.016893516936880078To get the average relative standard deviations (ignoring the first prediction which is 0), we run:
mean(σs[2:end] ./ μs[2:end])0.02514125973331405So the predictions are not very sensitive to the parameter uncertainty.
5 Summary
In this tutorial, we have seen how to test for model non-identifiability using the Fisher information matrix and sensitivity analysis. We have shown that maximum likelihood estimation is unreliable when fitting poorly identifiable models. And we have seen how one can use Bayesian inference to: 1) fit non-identifiable or poorly identifiable models to data, 2) ask probabilistic questions of the model, and 3) simulate counter-factual scenarios.
6 References
- Thomas J. Rothenberg. Identification in parametric models. Econometrica, 1971.
- F. Mentre, A Mallet, and D. Baccar. Optimal design in random-effects regression models. Biometrika, 1997.
- S. Retout and F Mentre. Further development of the fisher information matrix in nonlinear mixed-effects models with evaluation in population pharmacokinetics. Journal of biopharmaceutical statistics, 2003.
- V. Shivva, K. Korell, I. Tucker, and S. Duffull. An approach for identifiability of population pharmacokinetic-pharmacodynamic models. CPT Pharmacometrics & Systems Pharmacology, 2013.
- Stephen Dufful, A workflow for resolving model internal consistency in use-reuse settings (aka repairing unstable models). PAGANZ, 2024.
- Dan Wright. The identifiability of a turnover model for allopurinol urate-lowering effect. PAGANZ, 2024.