using Pumas
Fitting Non-Identifiable and Poorly Identifiable Models using Bayesian Inference
In this tutorial, we will see how to use Bayesian inference in Pumas to fit a non-identifiable (or a poorly identifiable) model by sampling from the full posterior. Unlike maximum likelihood estimation methods which only find point estimates for the model parameters, Bayesian methods can be used to sample from the full posterior of the model parameters making it more robust to identifiability issues.
1 Model Identifiability
One of the goals of statistical learning is to identify the underlying parameter values in a parametric model that best fit the observed data. In many practical scenarios, some parameters in a model may not be identifiable, for one of the following problems:
- The model is over-parameterized with redundant parameters, where a continuum of parameter values, e.g \(0 \leq \theta \leq 1\), would all give identical model predictions. This tends to happen when a dynamical model has many compartments and associated parameters but only one or a few compartments are observed. Another case where this happens is if there is a typo in the model where a parameter is not used everywhere it should.
- The model has symmetries such that a discrete set of parameter values, e.g. \(\theta = -1\) or \(\theta = 1\), give identical model predictions. This tends to happen with inappropriate use of the “absolute value” function (
abs) if used on a function that can be either negative or positive potentially creating 2 separate modes. This problem can sometimes be fixed by using appropriate parameter bounds, e.g. \(\theta \geq 0\), in the model. - The data is insufficient to learn some parameters’ values but more data would have been sufficient.
The first 2 problems are problems in the model describing structural non-identifiability and the third problem is a problem in the data or data-model mismatch describing practical non-identifiability (sometimes called non-estimability).
| Type of Identifiability | Description |
|---|---|
| Globally Structurally Identifiable | Every set of parameter values \(\theta\) makes a unique model prediction \(\mu(\theta)\). |
| Globally Practically Identifiable | Globally structurally identifiable and there is enough data to estimate the data-generating parameter values. |
| Locally Structurally Identifiable | Only dis-connected parameters values \(\{\theta_1, \theta_2, \dots, \theta_m\}\) can result in the same model prediction \(\mu\), i.e. \(\mu(\theta_1) = \mu(\theta_2) = \dots = \mu(\theta_m)\). However, in the neighborhood \(N(\theta)\) of each set of parameters \(\theta\), each \(\theta' \in N(\theta)\) results in a unique model prediction \(\mu(\theta')\). |
| Locally Practically Identifiable | Locally structurally identifiable and there is enough data to estimate the (potentially non-unique but dis-connected) data-generating parameter values. |
Key Points
- Local (or global) practical identifiablity is what we usually want in analyses.
- Practical identifiability (estimability) implies structural identifiability.
Poor Identifiability
When a model may be identifiable in exact arithmetic but its identifiability is sensitive to numerical errors in computations, we will call it poorly identifiable. When the term “poorly identifiable models” is used in the rest of this tutorial, this also includes truly non-identifiable models.
2 Example
Let’s consider an example of fitting a poorly identifiable model.
2.1 Loading Pumas
First, let’s load Pumas:
2.2 Two Compartment Model
Now let’s define a single-subject, 2-compartment model with a depot, central and peripheral compartments and a proportional error model.
model = @model begin
@param begin
θ ∈ VectorDomain(lower = zeros(5))
σ ∈ RealDomain(lower = 0.0)
end
@pre begin
CL = θ[1]
Vc = θ[2]
Ka = θ[3]
Vp = θ[4]
Q = θ[5]
end
@dynamics begin
Depot' = -Ka * Depot
Central' = Ka * Depot - (CL + Q) / Vc * Central + Q / Vp * Peripheral
Peripheral' = Q / Vc * Central - Q / Vp * Peripheral
end
@derived begin
cp := @. Central / Vc
dv ~ @. Normal(cp, abs(cp) * σ + 1e-6)
end
endPumasModel
Parameters: θ, σ
Random effects:
Covariates:
Dynamical variables: Depot, Central, Peripheral
Derived: dv
Observed: dv
Subject Model vs Population Model
Note that studying the identifiability of subject models is still relevant when fitting a population version of the model with typical values and random effects. The reason is that when evaluating the log likelihood using the Laplace method or first-order conditional estimation (FOCE), one of the steps involved is finding the empirical Bayes estimates (EBE) which is essentially fitting a subject’s version of the model, fixing population parameters and estimating random effects. Non-identifiability in the EBE estimation can often cause the EBE estimation to fail or to be so numerically unstable that the population parameters’ fit itself fails because the marginal likelihood (and its gradient) computed with Laplace/FOCE relied on incorrect or numerically unstable EBEs.
2.3 Parameter Values
Let’s define some parameter values to use for simulation.
params = (θ = [35, 100, 0.5, 210, 30], σ = 0.1)(θ = [35.0, 100.0, 0.5, 210.0, 30.0],
σ = 0.1,)2.4 Subject Definition
Next we define a subject skeleton with a single bolus dose and no observations.
skeleton = Subject(
id = 1,
time = 0.0:0.5:30.0,
events = DosageRegimen(3000, time = 0.0, cmt = 1),
observations = (; dv = nothing),
)Subject
ID: 1
Events: 1
Observations: dv: (n=61)2.5 Fisher Information Matrix
The expected Fisher Information Matrix (FIM) is an important diagnostic which can be used to detect local practical identifiability (LPI) given the model and the experiment design [1]. The first order approximation of the expected FIM [2,3] has also been used successfully to analyze the LPI of pharmacometric nonlinear mixed effect (NLME) models [4,5,6].
The positive definiteness (non-singularity) of the expected FIM \(F(\theta)\) at parameters \(\theta\) is a sufficient condition for LPI at \(\theta\). Under more strict assumptions which are more difficult to verify, the positive definiteness of \(F(\theta)\) is even a necessary condition for LPI [1].
To compute a first-order approximation of the expected FIM, we will use the OptimalDesign package:
using OptimalDesign
times = OptimalDesign.ObsTimes(skeleton.time)
F = OptimalDesign.fim(model, [skeleton], params, [times], FO())6×6 Symmetric{Float64, Matrix{Float64}}:
1.29489 -0.0538762 13.6934 0.0254882 -0.218694 -2.68028
-0.0538762 0.0188821 -4.38015 -0.00168545 0.0296863 -0.325336
13.6934 -4.38015 1054.71 0.635262 -7.13309 66.7482
0.0254882 -0.00168545 0.635262 0.00215196 -0.00487912 -0.0895271
-0.218694 0.0296863 -7.13309 -0.00487912 0.144604 -0.720992
-2.68028 -0.325336 66.7482 -0.0895271 -0.720992 1667.742.6 Procedure for Detecting Practical Non-Identifiability
Next, let’s do an eigenvalue decomposition of F to find the smallest eigenvalue. The smallest eigenvalue is always the first one because they are sorted.
E = eigen(F)
E.values[1]9.646842560391092e-5It is close to 0! This implies that the matrix is very close to being singular. While this is not strictly a proof of local non-identifiability, it is one step towards detecting non-identifiability.
Tip
The non-singularity of the expected FIM is generally only a sufficient (not necessary) condition for local identifiability. So there are some locally identifiable models that have a singular or undefined expected FIM. However, there is a subclass of models satisfying strict assumptions for which the non-singularity of the expected FIM is a necessary condition for local identifiability [1]. In practice, these assumptions are difficult to verify for a general model but if our model happens to satisfy these assumptions, then a singular expected FIM would imply local non-identifiability. In that case, the eigenvector(s) corresponding to the 0 eigenvalue would be useful diagnostics as they point in the directions along which changes in the parameters will have no effect on the log likelihood.
To summarize:
- Being “Non-Singular” Isn’t Always a Must: A non-singular expected FIM always signals that a model is “locally identifiable” (meaning you can find a locally unique solution for its parameters). However, some locally identifiable models can still have singular or undefined expected FIM.
- Sometimes, It’s Absolutely Necessary: There’s a special group of models where a non-singular expected FIM is required to be locally identifiable. It’s hard to know if your model falls into this group.
- Practical Use: Even if your expected FIM is singular, it may be a helpful diagnostic. The eigenvectors of the FIM with 0 eigenvalues show you directions where changing the model’s parameters may not affect the model’s predictions – this may help you pinpoint where the model is fuzzy.
To prove if a model is practically non-identifiable, it suffices to find a single set \(\Theta\) such that for all parameters \(\theta \in \Theta\), the log likelihood is unchanged. To find \(\Theta\) numerically, one can
- Assume parameter values \(\theta_0\),
- Define a criteria for changing the parameters \(\theta\) from their current values \(\theta_0\), and then create a candidate set of parameters \(\Theta_c\),
- Simulate synthetic data using the parameters \(\theta_0\),
- Evaluate the log likelihood \(L(\theta)\) for all \(\theta \in \Theta_c\),
- Evaluate the sensitivity of the log likelihood to local changes within \(\Theta_c\).
One way to construct a candidate \(\Theta_c\) is as the set \(\{\theta_0 + \alpha \cdot d : \alpha \in [-\epsilon, \epsilon] \}\) for a small \(\epsilon > 0\), where \(d\) is an eigenvector corresponding to the smallest eigenvalue of the expected FIM, \(F\). The sensitivity of the log likelihood to changes within \(\Theta_c\) can then be quantified as the average value of:
\[ \Bigg( \frac{L(\theta_0 + \alpha \cdot d) - L(\theta_0)}{\alpha} \Bigg)^2 \]
for all \(\alpha \in [-\epsilon, \epsilon]\), \(\alpha \neq 0\). Let’s follow this procedure for the above model assuming \(\theta_0\) is params.
2.7 Simulating Data
Here we simulate a synthetic subject using the skeleton subject we have. We fix the seed of the pseudo-random number generator for reproducibility.
using Random
rng = Random.default_rng()
Random.seed!(rng, 12345)
pop = [Subject(simobs(model, skeleton, params; rng))]Population
Subjects: 1
Observations: dvTo evaluate the log likelihood of params given pop, we can use the loglikelihood function:
ll0 = loglikelihood(model, pop, params, NaivePooled())32.82461166030995Since there are no random effects in this model, we use the NaivePooled() algorithm in Pumas.
2.8 Local Sensitivity Analysis of Log Likelihood
The eigenvectors corresponding to the smallest eigenvalue of F give us the directions that are likely to have the largest standard error in the maximum likelihood estimates. These are the most promising directions to test when constructing candidate sets \(\Theta_c\) for identifiability analysis. To get the eigenvector corresponding to the smallest eigenvalue, you can run:
d = E.vectors[:, 1]6-element Vector{Float64}:
0.006717009021480594
0.838273117515353
0.0037560578470210585
-0.5451738773538755
0.004939403956432533
-3.1373523445333997e-6The order of parameters is the same as the order of definition in the model: θ and then σ.
Note that the potential non-identifiability seems to be mostly in the second and fourth parameter, Vc and Vp. More precisely, the above eigenvector implies that simultaneously increasing Vc and decreasing Vp (or vice versa) by the ratios given in d may have little to no effect on the log likelihood.
Let’s try to add α * d[1:end-1] to params.θ (i.e. move params.θ in the direction d[1:end-1]) and evaluate the log likelihood for different step sizes α. To do that, we will first define a function that moves params.θ and call it on different step values α. These choices of α values correspond to a discrete candidate set \(\Theta_c\).
function moveθ(α)
# unpacking the fields of params to variables with the same names
(; θ, σ) = params
# move θ by step * d[1:end-1]
return (; θ = θ + α * d[1:end-1], σ)
end
# move by both negative and positive steps (excluding α = 0)
αs = vcat(-1e-3 .* (1:10), 1e-3 .* (1:10))20-element Vector{Float64}:
-0.001
-0.002
-0.003
-0.004
-0.005
-0.006
-0.007
-0.008
-0.009
-0.01
0.001
0.002
0.003
0.004
0.005
0.006
0.007
0.008
0.009
0.01newparams = moveθ.(αs)20-element Vector{NamedTuple{(:θ, :σ), Tuple{Vector{Float64}, Float64}}}:
(θ = [34.99999328299098, 99.99916172688249, 0.499996243942153, 210.00054517387736, 29.999995060596042], σ = 0.1)
(θ = [34.999986565981956, 99.99832345376497, 0.49999248788430595, 210.0010903477547, 29.999990121192088], σ = 0.1)
(θ = [34.999979848972934, 99.99748518064746, 0.4999887318264589, 210.00163552163207, 29.99998518178813], σ = 0.1)
(θ = [34.99997313196391, 99.99664690752994, 0.4999849757686119, 210.00218069550942, 29.999980242384176], σ = 0.1)
(θ = [34.99996641495489, 99.99580863441243, 0.49998121971076487, 210.00272586938678, 29.999975302980218], σ = 0.1)
(θ = [34.99995969794587, 99.9949703612949, 0.4999774636529179, 210.00327104326414, 29.99997036357626], σ = 0.1)
(θ = [34.99995298093685, 99.9941320881774, 0.49997370759507087, 210.0038162171415, 29.999965424172306], σ = 0.1)
(θ = [34.999946263927825, 99.99329381505987, 0.49996995153722384, 210.00436139101882, 29.999960484768348], σ = 0.1)
(θ = [34.99993954691881, 99.99245554194236, 0.4999661954793768, 210.00490656489617, 29.999955545364394], σ = 0.1)
(θ = [34.99993282990979, 99.99161726882484, 0.4999624394215298, 210.00545173877353, 29.999950605960436], σ = 0.1)
(θ = [35.00000671700902, 100.00083827311751, 0.500003756057847, 209.99945482612264, 30.000004939403958], σ = 0.1)
(θ = [35.000013434018044, 100.00167654623503, 0.500007512115694, 209.9989096522453, 30.000009878807912], σ = 0.1)
(θ = [35.000020151027066, 100.00251481935254, 0.500011268173541, 209.99836447836793, 30.00001481821187], σ = 0.1)
(θ = [35.00002686803609, 100.00335309247006, 0.5000150242313881, 209.99781930449058, 30.000019757615824], σ = 0.1)
(θ = [35.00003358504511, 100.00419136558757, 0.5000187802892351, 209.99727413061322, 30.000024697019782], σ = 0.1)
(θ = [35.00004030205413, 100.0050296387051, 0.5000225363470822, 209.99672895673586, 30.00002963642374], σ = 0.1)
(θ = [35.00004701906315, 100.0058679118226, 0.5000262924049291, 209.9961837828585, 30.000034575827694], σ = 0.1)
(θ = [35.000053736072175, 100.00670618494013, 0.5000300484627762, 209.99563860898118, 30.000039515231652], σ = 0.1)
(θ = [35.00006045308119, 100.00754445805764, 0.5000338045206232, 209.99509343510383, 30.000044454635606], σ = 0.1)
(θ = [35.00006717009021, 100.00838273117516, 0.5000375605784703, 209.99454826122647, 30.000049394039564], σ = 0.1)Now let’s evaluate the log likelihoods of all these parameter sets.
lls = map(newparams) do p
loglikelihood(model, pop, p, NaivePooled())
end20-element Vector{Float64}:
32.82463258809284
32.82465351677692
32.824674445999534
32.82469537568664
32.8247163049838
32.82473723582011
32.824758166021475
32.82477909749685
32.824800029291914
32.82482096111196
32.82459073300793
32.82456980632111
32.824548879812774
32.82452795380581
32.824507026997516
32.82448610281618
32.82446517756844
32.82444425406282
32.82442333007409
32.82440240653993To compute the average sensitivity within \(\Theta_c\), we then call:
sens = abs2.((lls .- ll0) ./ αs)
mean(sens)0.00043796889096800245Not very sensitive! Therefore, we can conclude that the log likelihood is almost the same inside \(\Theta_c\). This is a strong sign of non-identifiability, or at least poor identifiability.
Let’s contrast this with a random direction d2:
d2 = normalize(rand(6))
function moveθ2(α)
# unpacking the fields of params to variables with the same names
(; θ, σ) = params
# move θ by step * d2[1:end-1]
return (; θ = θ + α * d2[1:end-1], σ)
end
newparams2 = moveθ2.(αs)
lls2 = map(newparams2) do p
loglikelihood(model, pop, p, NaivePooled())
end
sens2 = abs2.((lls2 .- ll0) ./ αs)
mean(sens2)2647.7121385153137Notice the difference in sensitivity compared to a random direction.
Note
In practice, it can be difficult to be definitive about practical non-identifiability with numerical tests due to the nature of computation in floating point numbers where numerical errors can accumulate and either:
- Mask a truly singular matrix by reporting its smallest eigenvalue as very close to 0 but not exactly 0 in floating point numbers, or
- Make a truly non-singular matrix appear singular because its smallest eigenvalue was close to 0 in exact arithmetic but was computed as exactly 0 in floating point arithmetic.
A small enough average local sensitivity can therefore be taken as numerically equivalent to 0, i.e. local practical non-identifiability. To be more general, we will sometimes use the term poor identifiability to refer to the case when the model is approximately non-identifiable.
3 Fitting a Poorly Identifiable Model
3.1 Maximum Likelihood Estimation
When using maximum likelihood (ML) estimation to fit a poorly identifiable model, the parameter values you get can be dependent on arbitrary factors such as:
- The initial parameter estimates. Optimization algorithms will typically converge to values close to the initial value which is arbitrary.
- Level of noise in the data. Different levels of noise in the data can cause the optimization algorithm to take different trajectories reaching different optimal parameter values at the end.
- The implementation details of the optimization algorithm. For example, some optimization algorithms implicitly favor parameter values with the smallest norm.
Most of these factors have no statistical significance and can be considered arbitrary in any analysis. Therefore, any insights drawn from poorly identifiable parameter values fitted with ML estimation may be flawed. Luckily, the standard error estimation, if done right, will often reveal signs of poor identifiability. However, common techniques for estimating standard errors can often break down when the model is poorly identifiable. For instance,
- Asymptotic estimates of standard errors require the model to be locally identifiable,
- Bootstrap relies on the same arbitrary optimization algorithm for fitting the data resamples so its estimates are as unreliable as the ML estimates. For instance, since all the re-fits in bootstrapping are typically initialized from the ML estimates, there is a high probability that the optimization algorithm will only converge to nearby values, significantly under-estimating the variance in the ML estimates.
- Sampling importance resampling (SIR) may be able to handle non-identifiable models but it requires a good proposal and its results are sensitive to the proposal used.
Example: Sensitivity to Initial Estimates
Let’s fit the model to the same subject but with 2 different sets of initial estimates:
params1 = (θ = [35, 100, 0.5, 210, 30], σ = 0.1)
fpm1 = fit(model, pop, params1, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 -3.282461e+01 5.896801e+01
* time: 0.01713705062866211
1 -3.299541e+01 8.371540e+01
* time: 0.38966989517211914
2 -3.440867e+01 3.937303e+01
* time: 0.39004993438720703
3 -3.550285e+01 3.429323e+01
* time: 0.39036989212036133
4 -3.585802e+01 2.078146e+01
* time: 0.39069199562072754
5 -3.605801e+01 4.208231e+00
* time: 0.39100098609924316
6 -3.606867e+01 5.500193e+00
* time: 0.39127206802368164
7 -3.607820e+01 5.143560e-01
* time: 0.3915369510650635
8 -3.607823e+01 1.670014e-01
* time: 0.3918130397796631
9 -3.607823e+01 6.594663e-03
* time: 0.39208006858825684
10 -3.607823e+01 3.931885e-03
* time: 0.392348051071167
11 -3.607823e+01 5.365692e-02
* time: 0.3926229476928711
12 -3.607823e+01 2.875447e-02
* time: 0.39288806915283203
13 -3.607823e+01 3.163436e-03
* time: 0.393157958984375
14 -3.607823e+01 1.189357e-04
* time: 0.39342498779296875FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: 36.078234
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
-----------------
Estimate
-----------------
θ₁ 34.397
θ₂ 103.17
θ₃ 0.46566
θ₄ 204.44
θ₅ 26.234
σ 0.092273
-----------------params2 = (θ = [10.0, 300, 1.0, 10.0, 5], σ = 0.2)
fpm2 = fit(model, pop, params2, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 4.245135e+02 6.802168e+02
* time: 1.6927719116210938e-5
1 1.499850e+02 4.520555e+01
* time: 0.0003387928009033203
2 1.436201e+02 4.485781e+01
* time: 0.0006299018859863281
3 1.108786e+02 4.698780e+01
* time: 0.0009169578552246094
4 9.146731e+01 4.889574e+01
* time: 0.0012018680572509766
5 8.587677e+01 4.879782e+01
* time: 0.0015308856964111328
6 8.353852e+01 5.068832e+01
* time: 0.0018649101257324219
7 8.061237e+01 4.922992e+01
* time: 0.002199888229370117
8 7.723482e+01 3.939427e+01
* time: 0.002526998519897461
9 7.347395e+01 6.732180e+01
* time: 0.0028150081634521484
10 6.467070e+01 2.181937e+01
* time: 0.003113985061645508
11 5.389941e+01 4.260986e+01
* time: 0.003443002700805664
12 4.899559e+01 4.746853e+01
* time: 0.0037689208984375
13 4.636064e+01 4.389414e+01
* time: 0.004058837890625
14 4.311120e+01 3.667380e+01
* time: 0.004349946975708008
15 3.452695e+01 4.210878e+01
* time: 0.00467681884765625
16 2.786722e+01 4.181505e+01
* time: 0.005012989044189453
17 2.167865e+01 2.502622e+01
* time: 0.005342006683349609
18 2.102586e+01 3.073394e+01
* time: 0.00562596321105957
19 2.012361e+01 9.155807e+00
* time: 0.005917787551879883
20 1.993999e+01 8.931312e+00
* time: 0.0062007904052734375
21 1.899136e+01 3.290288e+01
* time: 0.006491899490356445
22 1.831295e+01 1.555682e+01
* time: 0.0067789554595947266
23 1.764099e+01 4.156267e+00
* time: 0.00707697868347168
24 1.734278e+01 4.764556e+00
* time: 0.0073699951171875
25 1.692204e+01 5.545119e+00
* time: 0.0076639652252197266
26 1.576409e+01 6.312615e+00
* time: 0.008022785186767578
27 1.433866e+01 8.298690e+00
* time: 0.008385896682739258
28 1.402269e+01 1.935483e+01
* time: 0.00874185562133789
29 1.388982e+01 5.313932e+00
* time: 0.009055852890014648
30 1.380201e+01 6.598677e+00
* time: 0.009372949600219727
31 1.361376e+01 1.819842e+01
* time: 0.009683847427368164
32 1.307080e+01 3.715687e+01
* time: 0.010008811950683594
33 1.084754e+01 4.989797e+01
* time: 0.010338783264160156
34 8.794420e+00 2.745244e+01
* time: 0.017780780792236328
35 7.967295e+00 6.289499e+01
* time: 0.018234968185424805
36 5.930144e+00 1.204447e+02
* time: 0.018590927124023438
37 1.324357e+00 7.168667e+01
* time: 0.018942832946777344
38 -3.676837e+00 5.009547e+01
* time: 0.019353866577148438
39 -7.679948e+00 6.799259e+01
* time: 0.01975083351135254
40 -8.111634e+00 7.739554e+01
* time: 0.02011394500732422
41 -9.112525e+00 4.521715e+01
* time: 0.020460844039916992
42 -9.288622e+00 8.096450e+00
* time: 0.020807981491088867
43 -9.348547e+00 4.137820e+00
* time: 0.0212099552154541
44 -9.351723e+00 5.725186e+00
* time: 0.021562814712524414
45 -9.357023e+00 6.979516e+00
* time: 0.021914958953857422
46 -9.368194e+00 7.993143e+00
* time: 0.022265911102294922
47 -9.397294e+00 8.502274e+00
* time: 0.022610902786254883
48 -9.476822e+00 5.319833e+00
* time: 0.02295684814453125
49 -9.560670e+00 2.647022e+01
* time: 0.023302793502807617
50 -9.923375e+00 4.001483e+01
* time: 0.023638010025024414
51 -1.067052e+01 1.385511e+01
* time: 0.02397298812866211
52 -1.076458e+01 6.836242e+00
* time: 0.02434396743774414
53 -1.086403e+01 2.969781e+01
* time: 0.02467799186706543
54 -1.094385e+01 1.854034e+01
* time: 0.025009870529174805
55 -1.098045e+01 1.501688e+01
* time: 0.025334835052490234
56 -1.101104e+01 2.337595e+00
* time: 0.025664806365966797
57 -1.101520e+01 1.310715e+00
* time: 0.025995969772338867
58 -1.101875e+01 2.317156e+00
* time: 0.026323795318603516
59 -1.101993e+01 3.135956e-01
* time: 0.026649951934814453
60 -1.102013e+01 1.295996e-01
* time: 0.026981830596923828
61 -1.102013e+01 6.093598e-03
* time: 0.027304887771606445
62 -1.102013e+01 6.093598e-03
* time: 0.027971982955932617FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: 11.020132
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
----------------
Estimate
----------------
θ₁ 30.963
θ₂ 214.26
θ₃ 55.566
θ₄ 169.43
θ₅ 12.071
σ 0.13904
----------------Now let’s display the estimates of θ side by side:
hcat(coef(fpm1).θ, coef(fpm2).θ)5×2 Matrix{Float64}:
34.3968 30.9629
103.168 214.262
0.465659 55.5661
204.442 169.426
26.2337 12.0707Notice the significant difference in the final estimates when changing nothing but the initial estimates. Also note that the 2 sets of coefficients are not in the same neighbourhood and don’t have similar log likelihoods. This is indicative of the existence of multiple dis-connected local optima.
Example: Sensitivity to Noise Level
To demonstrate the sensitivity to noise level, we will re-simulate the synthetic subject from the same pseudo-random number generator and seed but using a higher σ.
rng = Random.default_rng()
Random.seed!(rng, 12345)
newparams = (; θ = params.θ, σ = 0.2)
newpop = [Subject(simobs(model, skeleton, newparams; rng))]Population
Subjects: 1
Observations: dvNow let’s do the fit once with pop and once with newpop:
fpm1 = fit(model, pop, params, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 -3.282461e+01 5.896801e+01
* time: 1.7881393432617188e-5
1 -3.299541e+01 8.371540e+01
* time: 0.0004868507385253906
2 -3.440867e+01 3.937303e+01
* time: 0.0008749961853027344
3 -3.550285e+01 3.429323e+01
* time: 0.0012519359588623047
4 -3.585802e+01 2.078146e+01
* time: 0.0016407966613769531
5 -3.605801e+01 4.208231e+00
* time: 0.002029895782470703
6 -3.606867e+01 5.500193e+00
* time: 0.0023469924926757812
7 -3.607820e+01 5.143560e-01
* time: 0.0026597976684570312
8 -3.607823e+01 1.670014e-01
* time: 0.0029859542846679688
9 -3.607823e+01 6.594663e-03
* time: 0.003306865692138672
10 -3.607823e+01 3.931885e-03
* time: 0.0036268234252929688
11 -3.607823e+01 5.365692e-02
* time: 0.003950834274291992
12 -3.607823e+01 2.875447e-02
* time: 0.00426793098449707
13 -3.607823e+01 3.163436e-03
* time: 0.004585981369018555
14 -3.607823e+01 1.189357e-04
* time: 0.004907846450805664FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: 36.078234
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
-----------------
Estimate
-----------------
θ₁ 34.397
θ₂ 103.17
θ₃ 0.46566
θ₄ 204.44
θ₅ 26.234
σ 0.092273
-----------------fpm2 = fit(model, newpop, newparams, NaivePooled())[ Info: Checking the initial parameter values.
[ Info: The initial negative log likelihood and its gradient are finite. Check passed.
Iter Function value Gradient norm
0 8.763976e+00 2.735808e+01
* time: 1.1920928955078125e-5
1 8.405325e+00 2.531358e+01
* time: 0.0004589557647705078
2 6.620382e+00 1.286061e+01
* time: 0.0008440017700195312
3 5.297438e+00 8.779519e+00
* time: 0.001219034194946289
4 4.963913e+00 3.840318e+00
* time: 0.0015950202941894531
5 4.930293e+00 1.184668e+01
* time: 0.0019180774688720703
6 4.873975e+00 3.753008e+00
* time: 0.0022439956665039062
7 4.858307e+00 2.308575e+00
* time: 0.002630949020385742
8 4.854947e+00 8.434789e-02
* time: 0.0029609203338623047
9 4.854713e+00 7.173485e-02
* time: 0.0032820701599121094
10 4.853126e+00 8.197275e-01
* time: 0.0036020278930664062
11 4.851996e+00 1.269989e+00
* time: 0.0039288997650146484
12 4.850709e+00 1.179594e+00
* time: 0.004255056381225586
13 4.849908e+00 1.616557e-01
* time: 0.004578113555908203
14 4.849724e+00 8.747458e-01
* time: 0.0048999786376953125
15 4.849534e+00 1.703991e-01
* time: 0.005218029022216797
16 4.849431e+00 1.385412e-01
* time: 0.0055370330810546875
17 4.849400e+00 1.192473e-01
* time: 0.0058629512786865234
18 4.849395e+00 8.727131e-03
* time: 0.006179094314575195
19 4.849394e+00 2.408210e-02
* time: 0.006499052047729492
20 4.849394e+00 1.491009e-03
* time: 0.006824016571044922
21 4.849394e+00 1.658923e-04
* time: 0.007139921188354492FittedPumasModel
Successful minimization: true
Likelihood approximation: NaivePooled
Log-likelihood value: -4.8493937
Number of subjects: 1
Number of parameters: Fixed Optimized
0 6
Observation records: Active Missing
dv: 61 0
Total: 61 0
----------------
Estimate
----------------
θ₁ 33.85
θ₂ 125.52
θ₃ 0.50012
θ₄ 192.8
θ₅ 22.25
σ 0.18103
----------------Now let’s display the estimates of θ side by side:
hcat(coef(fpm1).θ, coef(fpm2).θ)5×2 Matrix{Float64}:
34.3968 33.8499
103.168 125.517
0.465659 0.500121
204.442 192.8
26.2337 22.2497Given that we have many observations per subject, this level of fluctuation due to a higher noise is a symptom of non-identifiability. Also note the big difference compared to the true data-generating parameter values!
params.θ5-element Vector{Float64}:
35.0
100.0
0.5
210.0
30.0
Summary
In this section, we have demonstrated beyond reasonable doubt that ML estimation workflows can be unreliable when fitting poorly identifiable models, potentially leading to erroneous conclusions in a study. So if we cannot rely on ML estimation for fitting poorly identifiable models, what can we use? The answer is Bayesian inference.
3.2 Bayesian Inference
Using Bayesian methods to sample from the posterior of the parameter estimates is a mathematically sound way to fit non-identifiable models because even non-identifiable models have a well-defined posterior distribution, when their parameters are assigned prior distributions. If multiple parameter values all fit the data well, then all such values will be plausible samples from the posterior distribution, assuming reasonable priors were used.
3.2.1 Model Definition
Let’s see how to minimally change our model above to make it Bayesian using a weakly informative priors “roughly in the ballpark”:
bayes_model = @model begin
@param begin
θ ~ MvLogNormal([log(50), log(150), log(1.0), log(100.0), log(10.0)], I(5))
σ ~ Uniform(0.0, 1.0)
end
@pre begin
CL = θ[1]
Vc = θ[2]
Ka = θ[3]
Vp = θ[4]
Q = θ[5]
end
@dynamics begin
Depot' = -Ka * Depot
Central' = Ka * Depot - (CL + Q) / Vc * Central + Q / Vp * Peripheral
Peripheral' = Q / Vc * Central - Q / Vp * Peripheral
end
@derived begin
cp := @. Central / Vc
dv ~ @. Normal(cp, abs(cp) * σ + 1e-6)
end
endPumasModel
Parameters: θ, σ
Random effects:
Covariates:
Dynamical variables: Depot, Central, Peripheral
Derived: dv
Observed: dv3.2.2 Sampling from the Posterior
Now to fit it, we need to pass an instance of BayesMCMC as the algorithm in fit. In this case, we used 4 chains for sampling with 3000 samples per chain out of which the first 1500 samples will be used to adapt the mass matrix and step size of the No-U-Turn sampler (NUTS) used in Pumas. All the chains are also parallelized using multi-threading.
# Setting the pseudo-random number generator's seed for reproducibility
rng = Pumas.default_rng()
Random.seed!(54321)
bayes_alg = BayesMCMC(;
nsamples = 3000,
nadapts = 1500,
nchains = 4,
ensemblealg = EnsembleThreads(),
rng,
)
bayes_fpm = fit(bayes_model, pop, params, bayes_alg)[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.
[ Info: Checking the initial parameter values.
[ Info: The initial log probability and its gradient are finite. Check passed.Chains MCMC chain (3000×6×4 Array{Float64, 3}):
Iterations = 1:1:3000
Number of chains = 4
Samples per chain = 3000
Wall duration = 33.02 seconds
Compute duration = 125.68 seconds
parameters = θ₁, θ₂, θ₃, θ₄, θ₅, σ
Summary Statistics
parameters mean std mcse ess_bulk ess_tail rhat ⋯
Symbol Float64 Float64 Float64 Float64 Float64 Float64 ⋯
θ₁ 34.2757 0.6481 0.0088 5474.9035 5253.1912 1.0002 ⋯
θ₂ 137.3035 35.2435 0.7239 2459.1076 4153.6327 1.0017 ⋯
θ₃ 0.6437 0.1845 0.0037 2429.0840 4151.9594 1.0018 ⋯
θ₄ 190.7239 18.7720 0.3435 3112.0848 5187.6398 1.0018 ⋯
θ₅ 23.3751 3.0288 0.0556 3024.2967 4928.7592 1.0011 ⋯
σ 0.0984 0.0098 0.0001 5752.6789 6058.0668 1.0008 ⋯
1 column omitted
Quantiles
parameters 2.5% 25.0% 50.0% 75.0% 97.5%
Symbol Float64 Float64 Float64 Float64 Float64
θ₁ 32.9915 33.8512 34.2750 34.7005 35.5457
θ₂ 70.5725 109.4919 140.6348 165.1281 197.1382
θ₃ 0.3455 0.4940 0.6355 0.7730 1.0242
θ₄ 159.0538 177.2611 188.5181 202.6944 231.6574
θ₅ 17.4391 21.2024 23.5577 25.5530 28.8604
σ 0.0813 0.0913 0.0977 0.1044 0.1196
Now let’s discard the NUTS warmup samples as burn-in:
bayes_fpm_samples = Pumas.discard(bayes_fpm, burnin = 1500)Chains MCMC chain (1500×6×4 Array{Float64, 3}):
Iterations = 1:1:1500
Number of chains = 4
Samples per chain = 1500
Wall duration = 33.02 seconds
Compute duration = 125.68 seconds
parameters = θ₁, θ₂, θ₃, θ₄, θ₅, σ
Summary Statistics
parameters mean std mcse ess_bulk ess_tail rhat ⋯
Symbol Float64 Float64 Float64 Float64 Float64 Float64 ⋯
θ₁ 34.2640 0.6446 0.0122 2832.1750 2481.7579 1.0003 ⋯
θ₂ 137.4383 35.5886 0.9666 1397.5326 2070.3411 1.0032 ⋯
θ₃ 0.6453 0.1865 0.0050 1373.6260 1982.9122 1.0032 ⋯
θ₄ 190.7747 19.1449 0.4712 1733.6292 2593.1761 1.0028 ⋯
θ₅ 23.3333 3.0587 0.0750 1698.6187 2715.7568 1.0020 ⋯
σ 0.0982 0.0099 0.0002 3304.8229 3203.8191 1.0004 ⋯
1 column omitted
Quantiles
parameters 2.5% 25.0% 50.0% 75.0% 97.5%
Symbol Float64 Float64 Float64 Float64 Float64
θ₁ 32.9873 33.8399 34.2652 34.6845 35.5321
θ₂ 69.7727 109.4919 140.9337 165.5866 198.0236
θ₃ 0.3436 0.4929 0.6392 0.7775 1.0280
θ₄ 158.4469 177.0631 188.5504 202.8676 232.6191
θ₅ 17.3623 21.0850 23.5006 25.5633 28.7869
σ 0.0809 0.0911 0.0975 0.1044 0.1192
Notice how Bayesian inference was able to quantify the uncertainty in the non-identifiable parameters (mostly θ₂ which is Vc and θ₄ which is Vp) reflected in the large standard deviation of the marginal posterior of some parameters, std, relative to its mean value, mean. This is consistent with the eigenvector d we used earlier to prove that the model is poorly identifiable which also showed the poor identifiability was mostly prevalent in these 2 parameters.
d6-element Vector{Float64}:
0.006717009021480594
0.838273117515353
0.0037560578470210585
-0.5451738773538755
0.004939403956432533
-3.1373523445333997e-63.2.3 Convergence Diagnostics
By default, we print summary statistics and a few convergence diagnostics: effective samples size (ess_bulk) and \(\hat{R}\) (rhat). In this case, the diagnostics look reasonable. The rhat is close to 1 and the minimum ess_bulk is around 1000.
Next we show the trace plot of all the parameters
using PumasPlots
trace_plot(bayes_fpm_samples; linkyaxes = false)
It can be seen that the chains are mostly well mixed. Occasional jumps seem to happen which may indicate the presence of another mode in the posterior with a relatively small probability mass.
Now let’s look at the auto-correlation plot:
autocor_plot(bayes_fpm_samples; linkyaxes = false)
Some auto-correlation seems to persist in some chains so let’s try some thinning, by keeping only one out of every 5 samples.
thin_bayes_fpm_samples = Pumas.discard(bayes_fpm, burnin = 1500, ratio = 0.2)
autocor_plot(thin_bayes_fpm_samples; linkyaxes = false)
Looks better!
To Thin Or Not To Thin
In general, thinning is not recommended unless there are extremely high levels of auto-correlation in the samples. This is because the thinned samples will always have less information than the full set of samples before thinning. However, we perform thinning in this tutorial for demonstration purposes.
3.2.4 Posterior Predictive Check
Now let’s do a posterior predictive check by first simulating 1000 scenarios from the posterior distribution of the response including residual noise.
obstimes = 0.0:0.5:30.0
sims = simobs(bayes_fpm_samples; samples = 1000, simulate_error = true, obstimes)[ Info: Sampling 1000 sample(s) from the posterior predictive distribution of each subject.Simulated population (Vector{<:Subject})
Simulated subjects: 1000
Simulated variables: dvthen we can do a visual predictive check (VPC) plot using the simulations
vpc_res = vpc(sims; observations = [:dv], ensemblealg = EnsembleThreads())
vpc_plt = vpc_plot(
vpc_res;
simquantile_medians = true,
observations = true,
axis = (xlabel = "Time (h)", ylabel = "Concentration", xticks = 0:2:30),
)[ Info: Detected 1000 scenarios and 1 subjects in the input simulations. Running VPC.
[ Info: Continuous VPC
Summary
With very few changes in the model and a few lines of code, we were able to obtain samples from the full posterior of the parameters of our poorly identifiable model.
4 Uncertainty Propagation, Queries and Decision Making
Just because a model is non-identifiable does not mean that the model is useless or less correct. In fact, more correct models that incorporate more biological processes tend to be non-identifiable because we can only observe/measure very few variables in the model, while simplified models are more likely to be identifiable. Given samples from the posterior of a non-identifiable model, one can do the following:
- Propagate the uncertainty forward to the predictions to get samples from the posterior predictive distribution, instead of relying on a single prediction using the ML estimates.
Value of Uncertainty Quantification
Parameter uncertainty due to structural non-identifiability will by definition have no effect on the model’s predictions when predicting the observed response. However, uncertainty due to practical non-identifiability, or otherwise insufficient data, can have an impact on the model’s predictions. In this case, basing decisions on the full posterior predictive distribution instead of a single prediction from the ML estimates will make the decisions more robust to parameter uncertainty due to insufficient observations and model misspecification.
- Ask probabilistic questions given your data. For example, what’s the probability that the drug effect is \(> 0\)? Or what’s the probability that the new drug
Ais better than the control drugBafter only 3 months of data? Or what’s the probability of satisfying a therapeutic criteria for efficacy and safety given the current dose? - What-if analysis (aka counter-factual simulation) and dose optimization. For example, you can make predictions assuming the subject is a pediatric using the model parameters’ posterior inferred from an adult’s data. Or you can test different dose levels to select the best dose according to some therapeutic criteria. This can also be done in the non-Bayesian setting.
4.1 Probabilistic Questions
In this section, we show how to
- Estimate the probability that a parameter is more than a specific value, and
- Estimate the probability that the subject satisfies a desired therapeutic criteria. From there, one can simulate multiple doses and choose the dose that maximizes this probability.
To estimate the probability that CL > 35, we can run:
mean(bayes_fpm_samples) do p
p.θ[1] > 35
end0.123To estimate the probability that a subject satisfies a desired therapeutic criteria, we first simulate from the posterior predictive distribution (without residual error):
ipreds = simobs(bayes_fpm_samples; samples = 1000, simulate_error = false, obstimes)[ Info: Sampling 1000 sample(s) from the posterior predictive distribution of each subject.Simulated population (Vector{<:Subject})
Simulated subjects: 1000
Simulated variables: dvNext, we can estimate the area-under-curve (auc) and maximum drug concentration (cmax) given the different posterior samples.
using NCA
nca_params = postprocess(ipreds) do gen, obs
pk_auc = NCA.auc(gen.dv, obstimes)
pk_cmax = NCA.cmax(gen.dv, obstimes)
(; pk_auc, pk_cmax)
end1000-element Vector{NamedTuple{(:pk_auc, :pk_cmax), Tuple{Float64, Float64}}}:
(pk_auc = 87.1495047941033, pk_cmax = 10.17857459746979)
(pk_auc = 86.91022711258748, pk_cmax = 9.823208732298932)
(pk_auc = 87.19029454161655, pk_cmax = 9.539623516463527)
(pk_auc = 85.18941996653493, pk_cmax = 9.769383654564088)
(pk_auc = 86.70005686147681, pk_cmax = 9.529338381523178)
(pk_auc = 86.64639383762075, pk_cmax = 9.57729678079066)
(pk_auc = 87.43498327063578, pk_cmax = 9.719930259455754)
(pk_auc = 86.97257400455534, pk_cmax = 9.667711783522194)
(pk_auc = 87.64809758331478, pk_cmax = 9.844809033062225)
(pk_auc = 86.50771947824654, pk_cmax = 9.616722019706149)
⋮
(pk_auc = 90.37615592669557, pk_cmax = 10.414844958250342)
(pk_auc = 88.85815440490254, pk_cmax = 10.382556080480754)
(pk_auc = 87.21508625698988, pk_cmax = 9.063711465104435)
(pk_auc = 87.53206565479505, pk_cmax = 9.856103406084546)
(pk_auc = 88.60389672855179, pk_cmax = 9.453208645141986)
(pk_auc = 84.13779776166604, pk_cmax = 9.317734356491277)
(pk_auc = 86.92404719235493, pk_cmax = 9.938258104419258)
(pk_auc = 89.8954248996865, pk_cmax = 10.441498783324974)
(pk_auc = 88.00546590967821, pk_cmax = 10.12263519061146)Finally, we can estimate the probability of satisfying a therapeutic criteria.
prob = mean(nca_params) do p
p.pk_auc > 90 && p.pk_cmax < 15.0
end0.034To compute the probability of efficacy and safety separately, one can instead run:
prob1 = mean(nca_params) do p
p.pk_auc > 90
end
prob2 = mean(nca_params) do p
p.pk_cmax < 15.0
end
prob1, prob2(0.034, 1.0)4.2 Counter-factual Analysis and Dose Optimization
After developing a model, one may be interested in simulating scenarios, e.g. different covariates or doses, that have not been observed in the data while reusing the same posterior distribution of the parameters learnt from the data. This can be used to select a new dose that maximizes the probabilities of efficacy and safety simultaneously given the previously observed data.
In Pumas, you can do this by defining a new subject that includes the new covariates or dose and then passing that to simobs. First, let’s define a new skeleton subject that represents our counter-factual scenario where a dose of 3200 was administered instead of the 3000 used in the observed case:
cf_skeleton = Subject(
id = 1,
time = 0.0:0.5:30.0,
events = DosageRegimen(3200, time = 0.0, cmt = 1),
observations = (; dv = nothing),
)Subject
ID: 1
Events: 1
Observations: dv: (n=61)To simulate from the posterior predictive distribution of this new subject using the posterior of the parameters, you can run:
cf_ipreds = simobs(
thin_bayes_fpm_samples,
cf_skeleton;
samples = 1000,
simulate_error = false,
obstimes,
subject = 1,
)[ Info: Simulating 1000 sample(s) from the posterior predictive distribution of subject 1 using the dose and covariates in the input subject.Simulated population (Vector{<:Subject})
Simulated subjects: 1000
Simulated variables: dvWe can then re-evaluate the probability of satisfying a therapeutic criteria:
cf_nca_params = postprocess(cf_ipreds) do gen, obs
pk_auc = NCA.auc(gen.dv, obstimes)
pk_cmax = NCA.cmax(gen.dv, obstimes)
(; pk_auc, pk_cmax)
end
cf_prob = mean(cf_nca_params) do p
p.pk_auc > 90 && p.pk_cmax < 15.0
end0.973We can see that the probability increased. To understand why, let’s look at the probabilities of the auc and cmax criteria separately:
cf_prob1 = mean(cf_nca_params) do p
p.pk_auc > 90
end
cf_prob2 = mean(cf_nca_params) do p
p.pk_cmax < 15.0
end
cf_prob1, cf_prob2(0.973, 1.0)Contrast this to the old dose’s probabilities:
prob1, prob2(0.034, 1.0)Note that this example was not particularly interesting because of the dense sampling which despite of it, the uncertainty in the parameters was still high. This implies that the uncertainty was largely due to structural identifiability issues in the model. Since uncertainty in parameters due to structural non-identifiability does not affect the model predictions, the posterior predictive distribution was much more concentrated than the parameters’ posterior.
To estimate the mean and standard deviation of the predictions at each point in time we can run:
μs = mean(ipreds) do gen, obs
gen.dv
end
σs = std(ipreds) do gen, obs
gen.dv
end61-element Vector{Float64}:
0.0
0.3288535991880955
0.40109701723470825
0.3815147123378599
0.34178734884397916
0.30549869552903874
0.27523124700292795
0.2482012985864182
0.22250582691000964
0.19790706166799968
⋮
0.014833412738392292
0.015185729690156736
0.0155791945486852
0.016000391422109937
0.01643782598490453
0.016881887204847904
0.01732469810295348
0.017759915121233715
0.018182514484507997To get the average relative standard deviations (ignoring the first prediction which is 0), we run:
mean(σs[2:end] ./ μs[2:end])0.025589613674887515So the predictions are not very sensitive to the parameter uncertainty.
5 Summary
In this tutorial, we have seen how to test for model non-identifiability using the Fisher information matrix and sensitivity analysis. We have shown that maximum likelihood estimation is unreliable when fitting poorly identifiable models. And we have seen how one can use Bayesian inference to: 1) fit non-identifiable or poorly identifiable models to data, 2) ask probabilistic questions of the model, and 3) simulate counter-factual scenarios.
6 References
- Thomas J. Rothenberg. Identification in parametric models. Econometrica, 1971.
- F. Mentre, A Mallet, and D. Baccar. Optimal design in random-effects regression models. Biometrika, 1997.
- S. Retout and F Mentre. Further development of the fisher information matrix in nonlinear mixed-effects models with evaluation in population pharmacokinetics. Journal of biopharmaceutical statistics, 2003.
- V. Shivva, K. Korell, I. Tucker, and S. Duffull. An approach for identifiability of population pharmacokinetic-pharmacodynamic models. CPT Pharmacometrics & Systems Pharmacology, 2013.
- Stephen Dufful, A workflow for resolving model internal consistency in use-reuse settings (aka repairing unstable models). PAGANZ, 2024.
- Dan Wright. The identifiability of a turnover model for allopurinol urate-lowering effect. PAGANZ, 2024.